Office 2013: Angepasste Word- und Excel-Standardvorlagen löschen

Word und Excel öffnen beim Start jeweils eine bestimmte Standard-Dokumentenvorlage. Diese gibt Formate, Schriftarten und einiges andere vor. Grundsätzlich lassen sich diese Vorlagen auch anpassen, damit neue Dokumente gleich passende Schriftarten usw. enthalten.

Leider ist das nicht immer unproblematisch, vor allem wenn die Anpassungen etwas umfangreicher sind. So ist es beispielsweise in manchen Situationen hinderlich, wenn die angepasste Word-Standardvorlage andere Seitenränder, eingebettete Logos oder bestimmte Formate verwendet. Dies kann sich dann äußern, wenn man automatische Funktionen oder Makros verwendet, die auf den vordefinierten Formaten beruhen und mit Anpassungen nicht richtig umgehen können. Ein Beispiel dafür ist die eingebaute Etiketten-Funktion von Word, die Etikettenformate nicht mehr richtig umsetzt, wenn die Seitenränder vom Installationsstandard abweichen.

Hier kann es sinnvoll sein, die angepassten Vorlagen zu löschen, um wieder mit den Installationsvorgaben von Office zu arbeiten. Eine Skriptlösung kann dies vereinfachen.

Die Speicherorte der angepassten Standardvorlagen unterscheiden sich je nach Windows- und Office-Version. In Office 2013 sind es diese Pfade:

• Word 2013 (Windows 7 und 8): %APPDATA%\Microsoft\Templates\Normal.dotm
• Excel 2013 (Windows 7 und 8): %APPDATA%\Microsoft\Excel\XLSTART\Mappe.xltx und Tabelle.xltx

Sobald diese Dateien vorhanden sind, binden Word bzw. Excel sie beim Programmstart als Standardvorlagen ein. Fehlen die Dateien, so starten beide Programme mit einer vordefinierten Vorlage.

In einer speziellen Situation habe ich zwei Skripte entwickelt, die die angepassten Vorlagen automatisch löschen und bei Bedarf dann Word oder Excel neu starten, damit die vordefinierten Vorlagen wieder verwendet werden. Dies war nötig, weil die angepassten Vorlagen über eine automatische Softwareverteilung verteilt wurden und so jeden Tag wieder neu im System waren. Als Notlösung, bis die Verteilung zentral geändert wurde, leisteten die Skripte gute Dienste. Sie eignen sich aber natürlich auch für einmaligen Gebrauch.

Hier die Skripte zum Download – Einsatz wie immer auf eigene Gefahr.

  Delete-WordExcelTemplates (1,1 KiB, 1.420-mal heruntergeladen, letzte Änderung am 3. September 2014)

Und hier zur Illustration der Skriptcode. Es handelt sich um einfache Batches, was in meiner Situation völlig ausreichte.

Jedes der Skripte prüft zunächst, ob Word bzw. Excel gerade läuft. Wenn ja, beendet es die Anwendung, wobei der Anwender noch nicht gespeicherte Daten speichern kann. Dann löscht das Skript die angepassten Vorlagendateien und startet die Applikation neu, wenn sie vorher bereits lief.

Delete-WordNormalDot.bat:

@ECHO OFF

REM check if winword.exe is running
REM if not, just go deleting
TASKLIST | FIND /I "winword.exe">NUL
IF %ERRORLEVEL%==1 GOTO execute

REM winword.exe seems to be running
SET wordruns=1
ECHO.
ECHO Please save or discard your document in Word, if any.
ECHO We will wait until it's done so you won't lose your data.
ECHO.

REM try to terminate winword.exe
REM the user will be prompted to save data if necessary
TASKKILL /IM winword.exe>NUL

:loop
REM wait until winword.exe has been terminated
TASKLIST | FIND /I "winword.exe">NUL
IF %ERRORLEVEL%==0 GOTO loop

:execute
REM now go and delete the custom normal.dotm file
REM so Word uses the default one
DEL "%APPDATA%\Microsoft\Templates\Normal.dotm"

REM launch winword.exe if it was running before
IF %wordruns%==1 START winword.exe

Delete-ExcelTemplates.bat:

@ECHO OFF

REM check if excel.exe is running
REM if not, just go deleting
TASKLIST | FIND /I "excel.exe">NUL
IF %ERRORLEVEL%==1 GOTO execute

REM excel.exe seems to be running
SET excelruns=1
ECHO.
ECHO Please save or discard your document in Excel, if any.
ECHO We will wait until it's done so you won't lose your data.
ECHO.

REM try to terminate excel.exe
REM the user will be prompted to save data if necessary
TASKKILL /IM excel.exe>NUL

:loop
REM wait until excel.exe has been terminated
TASKLIST | FIND /I "excel.exe">NUL
IF %ERRORLEVEL%==0 GOTO loop

:execute
REM now go and delete the custom template files
REM so Excel uses the default ones
DEL "%APPDATA%\Microsoft\Excel\XLSTART\Mappe.xltx"
DEL "%APPDATA%\Microsoft\Excel\XLSTART\Tabelle.xltx"

REM launch excel.exe if it was running before
IF %excelruns%==1 START excel.exe