Logo faq-o-matic.net
Logo faq-o-matic.net

Exchange 2007: Installation auf Windows Server 2008 vorbereiten

von veröffentlicht am21. April 2008, 15:11 Uhr Kurzlink und Zitatlink einblenden
Kategorie Kategorie: Exchange, Scripting, Windows Server 2008   Translate with Google Translate Translate EN   Die angezeigte Seite drucken
Zuletzt aktualisiert: 30. Dezember 2008

image Um Exchange Server 2007 auf Windows Server 2008 zu installieren, ist ein Installationsmedium mit (mindestens) dem integrierten Service Pack 1 für Exchange 2007 erforderlich. Doch auch der Server selbst muss vorbereitet sein, denn direkt nach der Installation fehlen ihm viele Komponenten, die Exchange 2007 benötigt. Der folgende Artikel listet die Komponenten auf und beschreibt gleichzeitig, wie man sie am einfachsten einrichtet:

[How to Install Exchange 2007 SP1 Prerequisites on Windows Server 2008 or Windows Vista]
http://technet.microsoft.com/en-us/library/bb691354(EXCHG.80).aspx

In vielen Umgebungen und in Testnetzwerken sollen alle vier produktiven Exchange-Rollen auf derselben Maschine installiert werden (also Mailbox Server [MB], Hub Transport Server [HT], Client Access Server [CAS] und Unified Messaging Server [UM]). Um dies noch weiter zu vereinfachen, habe ich die Komponenteninstallation in einem Batch zusammengefasst.

Die folgende Batchdatei gehört lokal auf den Server, auf dem Exchange Server 2007 eingerichtet werden soll (am besten in einen eigenen Ordner kopieren). Von dort wird sie dann ausgeführt. Leider aber hat Microsoft vor den Erfolg den Schweiß gesetzt: Die Verwaltungskomponente für Active Directory und die Media-Erweiterungen erfordern nach der Installation jeweils einen Neustart; sonst kann nicht weiter installiert werden. Daher ruft das Batch sie (anders als der oben zitierte Artikel) als letzte auf und führt dann jeweils gleich einen Neustart aus.

Das Batch ist mit einem simplen Prüfmechanismus versehen, weil es durch die Neustarts mehrfach aufgerufen werden muss: Sobald eine Komponente installiert wurde, schreibt das Batch eine Flagdatei. Ist diese vorhanden, wird die Komponente übersprungen. Das ist kein sicherer Mechanismus, dürfte für die gestellte Aufgabe aber völlig ausreichen. Die Batchdatei sollte in einem CMD-Fenster laufen, das ausdrücklich mit administrativen Rechten aufgerufen wurde. Achtung: In Zeile 7 darf nach den zwei Punkten am Ende kein Leerzeichen stehen (der Browser fügt beim Kopieren u.U. eins ein).

@echo off
rem Installieren der Voraussetzungen fuer Exchange 2007 SP1
rem auf Windows Server 2008
rem vgl. http://technet.microsoft.com/en-us/library/bb691354(EXCHG.80).aspx

rem Ordner fuer Logging setzen: Skriptordner
rem Achtung: Nach den zwei Punkten darf kein Leerzeichen stehen!
set folder=%0\..

:web-mgmt
if exist %folder%\web-mgmt.txt goto powershell
echo --- Installiere Web-Management-Voraussetzungen ...
ServerManagerCmd -i Web-Metabase
ServerManagerCmd -i Web-Lgcy-Mgmt-Console
echo web-mgmt OK>%folder%\web-mgmt.txt

rem *** mehrere Rollen (CAS, Hub, MB, UM)
:powershell
if exist %folder%\powershell.txt goto iis
echo --- Installiere PowerShell ...
ServerManagerCmd -i PowerShell
echo PowerShell OK>%folder%\powershell.txt

rem *** mehrere Rollen (CAS, MB)
:iis
if exist %folder%\iis.txt goto rpc
echo --- Installiere IIS-Komponenten ...
ServerManagerCmd -i Web-Server
ServerManagerCmd -i Web-ISAPI-Ext
ServerManagerCmd -i Web-Metabase
ServerManagerCmd -i Web-Lgcy-Mgmt-Console
ServerManagerCmd -i Web-Basic-Auth
ServerManagerCmd -i Web-Digest-Auth
ServerManagerCmd -i Web-Windows-Auth
ServerManagerCmd -i Web-Dyn-Compression
echo IIS OK>%folder%\iis.txt

rem *** CAS-Rolle
:rpc
if exist %folder%\rpc-proxy.txt goto desktop
echo --- Installiere OL Anywhere ...
ServerManagerCmd -i RPC-over-HTTP-proxy
echo rpc-proxy OK>%folder%\rpc-proxy.txt

rem *** UM-Rolle
:desktop
if exist %folder%\desktop-exp.txt goto rsat
echo --- Installiere Media-Extensions ...
ServerManagerCmd -i Desktop-Experience
echo Desktop-Exp OK>%folder%\desktop-exp.txt
echo.
echo ACHTUNG: Neustart erforderlich! Bitte danach das Batch neu starten!
echo.
echo Starte neu ...
shutdown -r -d p:2:4 /c "Desktop Experience installiert"

rem *** alle Rollen
:rsat
if exist %folder%\rsat-adds.txt goto fertig
echo --- Installiere AD-Verwaltungstool (RSAT-ADDS) ...
ServerManagerCmd -i RSAT-ADDS
rem Neustart erforderlich, daher Flagdatei schreiben
echo RSAT-ADDS OK>%folder%\rsat-adds.txt
echo.
echo ACHTUNG: Neustart erforderlich! Danach ist die Installation abgeschlossen.
echo.
echo Starte neu ...
shutdown -r -d p:2:4 /c "RSAT-ADDS installiert"

:fertig
echo.
echo --- Fertig!
pause

© 2005-2019 bei faq-o-matic.net. Alle Rechte an den Texten liegen bei deren Autorinnen und Autoren.

Jede Wiederveröffentlichung der Texte oder von Auszügen daraus - egal ob kommerziell oder nicht - bedarf der ausdrücklichen Genehmigung durch die jeweiligen Urheberinnen oder Urheber.

Das Impressum findet sich unter: http://www.faq-o-matic.net/impressum/

Danke, dass du faq-o-matic.net nutzt. Du hast ein einfaches Blog sehr glücklich gemacht!